[emacs] Enhance novHEADmaster

- count words
- skim forward and backward
- go to a random position

2 files changed, 103 insertions, 1 deletions

diff --git a/emacs/.emacs.d/lisp/my/my-emms.el b/emacs/.emacs.d/lisp/my/my-emms.el
index c2200c0..e8be5ee 100644
--- a/emacs/.emacs.d/lisp/my/my-emms.el
+++ b/emacs/.emacs.d/lisp/my/my-emms.el
@@ -531,6 +531,8 @@ Override `emms-mode-line-playlist-current' to incorporate wide chars."
         (my-emms-playlist-mark-bounds group-end)
         (emms-playlist-mode-play-current-track)))))
 
+;;; TODO: mark bounds if and only if the currently played is out of
+;;; the existing overlay.
 (defun my-emms-playlist-maybe-mark-bounds ()
   "Used as an `emms-player-started-hook'.
 
diff --git a/emacs/.emacs.d/lisp/my/my-nov.el b/emacs/.emacs.d/lisp/my/my-nov.el
index 0246be2..d43a8f3 100644
--- a/emacs/.emacs.d/lisp/my/my-nov.el
+++ b/emacs/.emacs.d/lisp/my/my-nov.el
@@ -41,8 +41,12 @@ chapter title."
     ;; this shouldn't happen for properly authored EPUBs
     (when (not title)
       (setq title "No title"))
+    ;; TODO: fix mode line update
     (setq mode-line-buffer-identification
-	        (concat title ": " chapter-title))
+          (format "%s: %s (%d%%)"
+	                title chapter-title
+                  (/ (* 100 (my-nov-word-position)) my-nov-total-word-count)
+                  ))
     ))
 
 (defun my-nov-render-span (dom)
@@ -88,5 +92,101 @@ Useful for recoll."
   (visual-line-mode)
   )
 
+(defvar-local my-nov-document-word-counts nil
+  "Word count of each nov document.")
+
+(defvar-local my-nov-total-word-count nil
+  "Total word count of the epub.")
+
+(defun my-nov-count-words ()
+  (interactive)
+  (unless my-nov-document-word-counts
+    (message "Counting words...")
+    (setq my-nov-document-word-counts
+          (apply
+           'vector
+           (seq-map
+            (lambda (doc)
+              (with-temp-buffer
+                (pcase-let ((`(,name . ,file) doc))
+                  (insert-file-contents file)
+                  (nov-render-html)
+                  (cons name (count-words (point-min) (point-max))))))
+            nov-documents)))
+    (setq my-nov-total-word-count
+          (seq-reduce
+           (lambda (sum pair)
+             (+ sum (cdr pair)))
+           my-nov-document-word-counts
+           0))
+    (message "Counting words...done")))
+
+(defun my-nov-stats ()
+  (interactive)
+  (message "%d words; %d standard pages"
+           my-nov-total-word-count
+           (ceiling (/ my-nov-total-word-count 300.0))))
+
+;;; TODO: also show current percentage in the total book in the mode
+;;; line
+(defun my-nov-goto-nth-word (n)
+  "Go to the nth word of the current epub."
+  (my-nov-count-words)
+  (setq nov-documents-index -1)
+  (let ((found
+         (seq-find
+          (lambda (pair)
+            (setq n (- n (cdr pair)))
+            (setq nov-documents-index (1+ nov-documents-index))
+            (<= n 0))
+          my-nov-document-word-counts)))
+    (nov-render-document)
+    (if (> n 0)
+        (end-of-buffer)
+      (forward-word (+ n (cdr found)))))
+  )
+
+(defun my-nov-word-position ()
+  "Where are we in terms of word position?
+
+Return n, such that nth word of the epub is at the beginning of the
+screen."
+  (my-nov-count-words)
+  (let ((result 0))
+    (dotimes (i nov-documents-index)
+      (setq result (+ result (cdr (aref my-nov-document-word-counts i)))))
+    (save-excursion
+      (move-to-window-line 0)
+      (setq result (+ result (count-words (point-min) (point)))))))
+
+(defun my-nov-skim-forward ()
+  "Forward by 3-10% of the book."
+  (interactive)
+  (let ((pc (+ 3 (random 8))))
+    (my-nov-goto-nth-word
+     (+ (my-nov-word-position)
+        (/ (* my-nov-total-word-count pc) 100)))
+    (message "Skimmed forward by %d%% of the book" pc)))
+
+(defun my-nov-skim-backward ()
+  "Backward by 3-10% of the book."
+  (interactive)
+  (let ((pc (+ 3 (random 8))))
+    (my-nov-goto-nth-word
+     (max
+      0
+      (- (my-nov-word-position)
+         (/ (* my-nov-total-word-count pc) 100))))
+    (message "Skimmed backward by %d%% of the book" pc)))
+
+(defun my-nov-goto-random-position ()
+  "Goto a random position in the epub."
+  (interactive)
+  (my-nov-count-words)
+  (let ((n (random my-nov-total-word-count)))
+    (my-nov-goto-nth-word n)
+    (message "Went to the %dth word (%d%% of the book)."
+             n (/ (* n 100) my-nov-total-word-count))))
+
 (provide 'my-nov)
 ;;; my-nov.el ends here