1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
|
;;; mastodon-auth.el --- Auth functions for mastodon.el -*- lexical-binding: t -*-
;; Copyright (C) 2017-2019 Johnson Denen
;; Author: Johnson Denen <johnson.denen@gmail.com>
;; Maintainer: Marty Hiatt <martianhiatus@riseup.net>
;; Version: 0.10.0
;; Package-Requires: ((emacs "27.1"))
;; Homepage: https://git.blast.noho.st/mouse/mastodon.el
;; This file is not part of GNU Emacs.
;; This file is part of mastodon.el.
;; mastodon.el is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; mastodon.el is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with mastodon.el. If not, see <http://www.gnu.org/licenses/>.
;;; Commentary:
;; mastodon-auth.el supports authorizing and authenticating with Mastodon.
;;; Code:
(require 'plstore)
(require 'auth-source)
(require 'json)
(eval-when-compile (require 'subr-x)) ; for if-let
(autoload 'mastodon-client "mastodon-client")
(autoload 'mastodon-http--api "mastodon-http")
(autoload 'mastodon-http--get-json "mastodon-http")
(autoload 'mastodon-http--post "mastodon-http")
(defvar mastodon-instance-url)
(defgroup mastodon-auth nil
"Authenticate with Mastodon."
:prefix "mastodon-auth-"
:group 'mastodon)
(defcustom mastodon-auth-source-file ""
"Filename to use to store user names and passwords.
Leave empty to not permanently store any secrets.
Otherwise set to e.g. \"~/.authinfo.gpg\" to have encrypted storage, or
if you are happy with unencryped storage use e.g. \"~/authinfo\"."
:group 'mastodon-auth
:type 'string)
(defvar mastodon-auth--token-alist nil
"Alist of User access tokens keyed by instance url.")
(defvar mastodon-auth--acct-alist nil
"Alist of account accts (name@domain) keyed by instance url.")
(defun mastodon-auth--get-browser-login-url ()
"Return properly formed browser login url."
(mastodon-http-append-query-string
(concat mastodon-instance-url "/oauth/authorize/")
`(("response_type" "code")
("redirect_uri" ,mastodon-client-redirect-uri)
("scope" ,mastodon-client-scopes)
("client_id" ,(plist-get (mastodon-client) :client_id)))))
(defvar mastodon-auth--explanation
(format
(concat "A URL has been copied to your clipboard.\n"
"Open this URL in a javascript capable browser.\n"
"Login to your account (%s) and authorize \"mastodon.el\".\n"
"Paste Authorization Code here: ")
(mastodon-client-form-user-from-vars)))
(defun mastodon-auth--ask-authorization-code ()
"Ask authorization code and return it."
(let ((url (mastodon-auth--get-browser-login-url))
authorization-code)
(kill-new url)
(setq authorization-code (read-string mastodon-auth--explanation))
authorization-code))
(defun mastodon-auth--generate-token ()
"Generate access_token for the user. Return response buffer."
(let ((authorization-code (mastodon-auth--ask-authorization-code)))
(mastodon-http--post
(concat mastodon-instance-url "/oauth/token")
`(("grant_type" . "authorization_code")
("client_secret" . ,(plist-get (mastodon-client) :client_secret))
("client_id" . ,(plist-get (mastodon-client) :client_id))
("code" . ,authorization-code)
("redirect_uri" . ,mastodon-client-redirect-uri))
nil
:unauthenticated)))
(defun mastodon-auth--get-token ()
"Make a request to generate an auth token and return JSON response."
(with-current-buffer (mastodon-auth--generate-token)
(goto-char (point-min))
(re-search-forward "^$" nil 'move)
(let ((json-object-type 'plist)
(json-key-type 'keyword)
(json-array-type 'vector)
(json-string (buffer-substring-no-properties (point) (point-max))))
(json-read-from-string json-string))))
(defun mastodon-auth--access-token ()
"Return exiting or generate new access token.
If an access token for `mastodon-instance-url' is in
`mastodon-auth--token-alist', return it.
Otherwise, generate a token and pass it to
`mastodon-auth--handle-token-reponse'."
(if-let ((token (cdr (assoc mastodon-instance-url mastodon-auth--token-alist))))
token
(mastodon-auth--handle-token-response (mastodon-auth--get-token))))
(defun mastodon-auth--handle-token-response (response)
"Add token RESPONSE to `mastodon-auth--token-alist'.
The token is returned by `mastodon-auth--get-token'.
Handle any errors from the server."
(pcase response
((and (let token (plist-get response :access_token))
(guard token))
(cdar (push (cons mastodon-instance-url token)
mastodon-auth--token-alist)))
(`(:error ,class :error_description ,error)
(error "Mastodon-auth--access-token: %s: %s" class error))
(_ (error "Unknown response from mastodon-auth--get-token!"))))
(defun mastodon-auth--get-account-name ()
"Request user credentials and return an account name."
(alist-get
'acct
(mastodon-http--get-json
(mastodon-http--api
"accounts/verify_credentials"))))
(defun mastodon-auth--user-acct ()
"Return a mastodon user acct name."
(or (cdr (assoc mastodon-instance-url mastodon-auth--acct-alist))
(let ((acct (mastodon-auth--get-account-name)))
(push (cons mastodon-instance-url acct) mastodon-auth--acct-alist)
acct)))
(provide 'mastodon-auth)
;;; mastodon-auth.el ends here
|
